Potion Stacking

[yeuyo]

Can anyone tell me how do you make the potion stacks?
Everytime I don't click me a potion it will use up another inventory slot even if there's only 1 charge there,is there a way to make it so that when you don't click me they all stack up together instead of wasting your inventory slots?

[weirdone2]

Have a trigger that when you don't click me the pot if theirs already the same pot in inventory then it will remove the one ur buying now and increase the charges of the one already in inventory.

[Ozzapoo]

=\ No way to make it automatically stack without triggers?

[Aero]

Haha, nope.

I made a block of jass code that stacks all charged items (To a constant limit ie: 50).
Post if interested . . .

[Ozzapoo]

Yes please!!!

[Hot]

Here it is, I'm also using this for my map.

Spoiler:

Item Stack
function Trig_Item_Stack_Conditions takes nothing returns boolean
return GetItemCharges(GetManipulatedItem()) > 0
endfunction

function Trig_Item_Stack_Actions takes nothing returns nothing
local integer i = 0
local item iteminslot
loop
set iteminslot = UnitItemInSlot(GetManipulatingUnit(), i)
if ( GetItemTypeId(iteminslot) == GetItemTypeId(GetManipulatedItem()) and iteminslot != GetManipulatedItem()) then
call SetItemCharges( iteminslot, ( GetItemCharges(iteminslot) + GetItemCharges(GetManipulatedItem()) ) )
call RemoveItem( GetManipulatedItem() )
set i = 5
// To end the loop i is increased
endif
set i = i + 1
exitwhen i > 5
endloop
set i = 0
set iteminslot = null
endfunction

// ==================
function InitTrig_Item_Stack takes nothing returns nothing
set gg_trg_Item_Stack = CreateTrigger( )
call TriggerRegisterAnyUnitEventBJ( gg_trg_Item_Stack, EVENT_PLAYER_UNIT_PICKUP_ITEM )
call TriggerAddCondition( gg_trg_Item_Stack, Condition( function Trig_Item_Stack_Conditions ) )
call TriggerAddAction( gg_trg_Item_Stack, function Trig_Item_Stack_Actions )
endfunction

Spoiler:

Item Move
function Trig_Item_Move_Conditions takes nothing returns boolean
return GetIssuedOrderId() > 852001 and GetIssuedOrderId() < 852008
endfunction


function Trig_Item_Move_Actions takes nothing returns nothing
local integer i = GetItemCharges(GetOrderTargetItem())
if GetOrderTargetItem() == UnitItemInSlot(GetOrderedUnit(), GetIssuedOrderId()-852002) then
// Clicked on the same field again



if i > 1 then
set i = i/2
call SetItemCharges(GetOrderTargetItem(), GetItemCharges(GetOrderTargetItem()) - i)
call DisableTrigger(gg_trg_Item_Stack)
call UnitAddItemByIdSwapped(GetItemTypeId(GetOrderTargetItem()), GetTriggerUnit())
call EnableTrigger(gg_trg_Item_Stack)
call SetItemCharges(bj_lastCreatedItem, i)
endif
else
// Clicked on another field



if i > 0 and GetItemTypeId(GetOrderTargetItem()) == GetItemTypeId(UnitItemInSlot(GetOrderedUnit(), GetIssuedOrderId()-852002)) then
call SetItemCharges(GetOrderTargetItem(), GetItemCharges(GetOrderTargetItem()) + GetItemCharges(UnitItemInSlot(GetOrderedUnit(), GetIssuedOrderId()-852002)))
call RemoveItem(UnitItemInSlot(GetOrderedUnit(), GetIssuedOrderId()-852002))
endif
endif
set i = 0
endfunction

//==============



function InitTrig_Item_Move takes nothing returns nothing
set gg_trg_Item_Move = CreateTrigger( )
call TriggerRegisterAnyUnitEventBJ( gg_trg_Item_Move, EVENT_PLAYER_UNIT_ISSUED_TARGET_ORDER )
call TriggerAddCondition( gg_trg_Item_Move, Condition( function Trig_Item_Move_Conditions ) )
call TriggerAddAction( gg_trg_Item_Move, function Trig_Item_Move_Actions )
endfunction

[Aero]

Optimized the code a bit for you and added 'max-stack' functionality.
Also added multi-distribution.

For example: Item a has 37 charges, Item b has 40 charges, MAX_STACK is 50. I pick up item c that has 23 charges. It will distribute to a and b--the resultant will be item c is gone, a and b have 50 charges. If you were to pick up item c with 26 charges, a and b would have 50 charges and c would have 3. Enjoy.

Spoiler:

Code: Select all

function Trig_Item_Stack_Conditions takes nothing returns boolean
return GetItemCharges(GetManipulatedItem())>0
endfunction

function Trig_Item_Stack_Actions takes nothing returns nothing
local integer MAX_STACK=50
local integer i=0
local integer a=0
local unit u=GetTriggerUnit()
local item manip=GetManipulatedItem()
local integer iid=GetItemTypeId(manip)
local integer charges=GetItemCharges(manip)
local item curr
loop
exitwhen i>5
set curr=UnitItemInSlot(u,i)
set a=GetItemCharges(curr)
if(GetItemTypeId(curr)==iid)and(curr!=manip)and(a<MAX_STACK)then
if charges<=MAX_STACK-a then
call SetItemCharges(curr,a+charges)
call RemoveItem(manip)
exitwhen true
else
call SetItemCharges(curr,MAX_STACK)
set charges=charges-MAX_STACK+a
call SetItemCharges(manip,charges)
endif
endif
set i=i+1
endloop
set curr=null
set manip=null
set u=null
endfunction

// ==================
function InitTrig_Item_Stack takes nothing returns nothing
set gg_trg_Item_Stack = CreateTrigger( )
call TriggerRegisterAnyUnitEventBJ( gg_trg_Item_Stack, EVENT_PLAYER_UNIT_PICKUP_ITEM )
call TriggerAddCondition( gg_trg_Item_Stack, Condition( function Trig_Item_Stack_Conditions ) )
call TriggerAddAction( gg_trg_Item_Stack, function Trig_Item_Stack_Actions )
endfunction

As a note: When looking to optimize, look at what you call more than necessary. If you see 5 "GetManipulatedItem()" calls, store GetManipulatedItem into a variable and just use the variable. Also, to exit a loop without the condition being true (i>5), use "exitwhen true".

[Aero]

God, nothing worse than people who ask for help and not even comment when they get it, let alone give thanks.
Makes me wonder why I bother

[Ozzapoo]

I was at school -.- No need to get so down....
And dont double-post

[yeuyo]

Er...actually I'm still figuring what all those means.